hd-webupload.cmd

@echo off
SETLOCAL EnableDelayedExpansion
echo.
echo HomeDing upload utility uploading web files to device.
echo.

REM == Default Values ==

set _webfolder=.\dist
set _curlopts=--retry 2
set _folder=dist
set _help=
set _clean=

if "%*"=="" ( set _help=1 )

:restart

REM == Option Values ==

if [%~1]==[--help] ( set _help=1 && shift /1 && goto :restart )
if [%~1]==[-h]     ( set _help=1 && shift /1 && goto :restart )
if [%~1]==[/h]     ( set _help=1 && shift /1 && goto :restart )
if [%~1]==[/?]     ( set _help=1 && shift /1 && goto :restart )

if [%~1]==[-c]      ( set _clean=1 && shift /1 && goto :restart )
if [%~1]==[--clean] ( set _clean=1 && shift /1 && goto :restart )

set devicename=%~1

if DEFINED _help (
  echo This utility enables uploading files from a folder into the filesystem of a device
  echo using http uploads.
  echo.
  echo To create the distribution files use npm run build and npm run pack
  echo.
  echo Usage: hd-webupload.bat [options] ^<devicename^> [folder]
  echo.  -h, --help     Get a brief help on using this tool
  echo.  -c, --clean    Clean existing files on device before upload
  echo.
  echo When no example parameter is given the files from the standard data folder are used.
  echo.
)

if NOT DEFINED devicename (
  echo.
  echo missing device name as parameter
  goto :end
)

if NOT [%~2]==[]  (
  set _webfolder=.\%~2
)

rem == execute == 

if DEFINED _clean (
  echo Cleaning...
  curl http://%devicename%/api/cleanweb
)

echo Uploading...
echo.  Device name = %devicename%
echo.  from folder = %_webfolder%
echo.

FOR %%F IN (%_webfolder%\*.*) DO (
  echo %%F
  curl --form "fileupload=@%%F;filename=/%%~nxF" http://%devicename%/ %_curlopts%
)

FOR %%F IN ("%_webfolder%\i\*.svg") DO (
  echo %%F
  curl --form "fileupload=@%%F;filename=/i/%%~nxF" http://%devicename%/ %_curlopts%
)

echo.
echo http://%devicename%/ updated.

:end

set _folder=
echo.